impresión de un ticket de venta

Hola buen día. Estoy haciendo un sistema en el que necesito imprimir un Ticket de venta (no se como se llama en España pero es el recibo que te dan las tiendas al comprar algo). Estoy programando en VBA Access. Realicé un informe le di el tamaño necesario etc. El problema es que al imprimir, me deja, al final un buen pedazo de papel en blanco, supongo que respetando un tamaño de papel. La impresora es térmica (POS Printer) e imprimo en un pedazo de rollo térmico.

Algún día, no hace mucho, programé en VBA de Excel un punto de venta y al seleccionar la impresora térmica, automáticamente ponía un tamaño de papel personalizado e imprimía el ticket perfectamente y del tamaño necesario.Yo suponía que en Access pararía lo mismo, pero no fue así.
¿Alguien me puede orientar que puedo hacer?

He buscado la palabra ticket en el foro pero sin éxito.
Gracias de antemano por su ayuda.

Gracias Jesus.
Estoy trabajando con este código:

Private Type DocInfo
    pDocName As String
    pOutputFile As String
    pDatatype As String
End Type

Private Declare PtrSafe Function ClosePrinter Lib "winspool.drv" (ByVal _
   hPrinter As Long) As Long
Private Declare PtrSafe Function EndDocPrinter Lib "winspool.drv" (ByVal _
   hPrinter As Long) As Long
Private Declare PtrSafe Function EndPagePrinter Lib "winspool.drv" (ByVal _
   hPrinter As Long) As Long
Private Declare PtrSafe Function OpenPrinter Lib "winspool.drv" Alias _
   "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, _
    ByVal pDefault As Long) As Long
Private Declare PtrSafe Function StartDocPrinter Lib "winspool.drv" Alias _
   "StartDocPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
   pDocInfo As DocInfo) As Long
Private Declare PtrSafe Function StartPagePrinter Lib "winspool.drv" (ByVal _
   hPrinter As Long) As Long
Private Declare PtrSafe Function WritePrinter Lib "winspool.drv" (ByVal _
   hPrinter As Long, pBuf As Any, ByVal cdBuf As Long, _
   pcWritten As Long) As Long


Public Function RawPrint(strData As String, ByVal SelectedPrinter As String)

Dim defprt As Printer
Dim lhPrinter As Long
Dim lReturn As Long
Dim lpcWritten As Long
Dim lDoc As Long
Dim sWrittenData As String
Dim mDocInfo As DocInfo
lReturn = OpenPrinter(SelectedPrinter, lhPrinter, 0)

If lReturn = 0 Then
    MsgBox "The Printer is not recognized."
    Exit Function
End If
mDocInfo.pDocName = "ZPl"
mDocInfo.pOutputFile = vbNullString
mDocInfo.pDatatype = vbNullString
lDoc = StartDocPrinter(lhPrinter, 1, mDocInfo)
Call StartPagePrinter(lhPrinter)
sWrittenData = strData
lReturn = WritePrinter(lhPrinter, ByVal sWrittenData, _
Len(sWrittenData), lpcWritten)
lReturn = EndPagePrinter(lhPrinter)
lReturn = EndDocPrinter(lhPrinter)
lReturn = ClosePrinter(lhPrinter)

End Function

Sub x()
    Call RawPrint("esto es una prueba", "\\DESKTOP-76ULVKL\POS58 10.0.0.6")
End Sub


Cuando lo ejecuto no hace nada. No marca error pero no imprime nada.
tuve que modificar lo de ptrsafe para que corra en maquina de 64 bits.
lo corro linea a linea pero desconozco cuál es el error.

tampoco estoy seguro si este código funciona con puertos USB. Y por más que bueco no encuentro nada.

Esto último es el camino a seguir ... he buscado lo que tenía en un programa antediluviano ... no es que esté muy depurado pero funciona:

Dim ImpresoraTickets As String . . ImpresoraTickets = "LPT3"    'era por puerto serie, puede ser LPT1, USB0001 - hay que buscar el nombre del puerto en la definición de la impresora Private Sub Abrir_cajon() 'Open "LPT1" For Output As #1     Open ImpresoraTickets For Output As #1     Print #1, Chr$(27); Chr$(112); Chr$(1); Chr$(255); Chr$(255);     Close #1 End Sub

- esto imprimía las líneas del tocket

Open ImpresoraTickets For Output As #1
Print #1, Chr$(27); "@";

For Contador1 = 1 To Contador
    Print #1, Chr$(27); "!"; Chr$(56); Matriz(Contador1, 1)
    Print #1, Chr$(27); "e"; Chr$(2); Chr$(27); "!"; Chr$(1); Chr$(27); "a"; Chr$(2); Matriz(Contador1, 2)
    Print #1, Chr$(27); "a"; Chr$(2); Matriz(Contador1, 3)
    Print #1, Chr$(27); "a"; Chr$(0); "Cli: "; Matriz(Contador1, 4)
    Print #1, ">> "; Matriz(Contador1, 5)
    Print #1, "   "; Matriz(Contador1, 6);
    Print #1, Chr$(27); "J"; Chr$(10)
    Print #1, Chr$(&H1D); "V"; Chr$(0)
    Print #1, Chr$(27); "e"; Chr$(1);
Next

Print #1, Chr$(27); "d"; Chr$(5)
Print #1, Chr$(&H1D); "V"; Chr$(0)
Close #1

Perdón por la demora pero estuve desconectado unos días.

De tu última aportación, el problema es que me crea un archivo llamado USB001 (de tipo texto) y en el escribe líneas como las siguientes:
@!8hola1
e!
ahola2
ahola3
a Cli: hola4
>> hola5
   hola6J

V
e
d
V
Que son los textos y "comandos escape" que deberían llegar a la impresora pero en lugar de eso llegan al archivo de texto.

Y no logro que llegue a la impresora.

Hola Jesús, después de dejar por un tiempo de intentarlo ayer me metí y por fin logre hacer lo que necesitaba. La solución la comparto para que otros la puedan tomar de aquí.

Esto sirve para impresoras GPrint China y creo que también las xPrint
En access o Excel en algún modulo:

Sub yy()
    Open "\\DESKTOP-66ULVKK\POS58" For Output As #1
    Print #1, Chr$(27) & Chr$(64)                   ' Reinicializa Impresora
    Print #1, Chr$(29); Chr$(33); Chr$(17)          ' Para Titulo
    Print #1, "RWJ SA DE CV"
    Print #1, Chr$(27) & Chr$(64)                   ' Tamaño por default
    Print #1, "Calle Oro 205"
    Print #1, "Colonia Leon II"
    Print #1, "Leon Guanajuato"
    Print #1, "--------------------------------"
    Print #1, "Cantidad / Producto"
    Print #1, "                  PU   /   Total"
    Print #1, "--------------------------------"
    Print #1, " 2 Coca cola Ligth 1 litro"
    Print #1, "            20.50       $ 41.00 "
    Print #1, Chr$(10)                            'Salto de línea
    Print #1, Chr$(29); Chr$(33); Chr$(1)        'Otro tamaño de letra
    Print #1, " TOTAL $ 41.00 "
    Print #1, Chr$(27) & Chr$(64)                 'Configuración inicial
    Print #1, Chr$(10)
    Close #1
End Sub

"\\DESKTOP-66ULVKK\POS58" ===>   Nombre de la computadora (DESKTOP-66ULVKK) y de la impresora (POS58)

La impresora ¡¡¡¡ TIENE QUE ESTAR COMPARTIDA !!!! eso me fallaba
debe estar en el puerto USB correcto (Propiedades de impresión) (panel control => Dispositivos e impresoras => La impresora que usas, en mi caso POS58 click derecho => propiedades de impresora => Puerto y también uso compartido ahí mismo.

Gracias a ti por la respuesta.